Einfaches Verfahren der Achse über die PLC

Voraussetzungen

• Ein TwinCAT-Projekt mit MC-Projekt wurde erstellt,
  siehe MC-Projekt erstellen.
• Eine Simulationsachse wurde im MC-Projekt angelegt,
  siehe Achsobjekt erstellen.
• Ein PLC-Projekt wurde im TwinCAT-Projekt angelegt.

PLC Bibliothek einbinden

PLC-Programm schreiben

Alle notwendigen Datentypen und Funktionsbausteine für ein einfaches PLC-Motion-Programm mit der MC3 sind in der Bibliothek Tc3_Mc3Ptp enthalten.

AXIS_REF

Je Achse wird eine Instanz vom Datentyp AXIS_REF benötigt, welche die Schnittstelle zwischen PLC und MC3 ist. Sie enthält alle Informationen zur Achse, die den MC-Funktionsbausteinen als Referenz mitgegeben werden.

MC_Power

Über den Funktionsbaustein MC_Power erfolgt die Freigabe der Achse und deren Bewegungsrichtung.

MC_SetOverride

Über den Funktionsbaustein MC_SetOverride kann der Geschwindigkeits-Override der Achse verändert werden. Standardmäßig ist der Faktor 1 (=100 %) hinterlegt, sodass eine Veränderung des Faktors optional ist.

MC_Reset

Mit dem Funktionsbaustein MC_Reset kann ein Fehler an einer Achse zurückgesetzt werden.

MC_MoveRelative

Mit dem Funktionsbaustein MC_MoveRelative kann die Achse um die definierte Distanz verfahren werden.

Einfache Programmierung

PROGRAM MAIN
VAR
    axis           : AXIS_REF;
    power          : MC_Power;
    setOverride    : MC_SetOverride;
    moveRelative   : MC_MoveRelative;
    reset          : MC_Reset;
    stop           : MC_Stop;
    enableAxis     : BOOL;
    enableOverride : BOOL;
    executeStop    : BOOL;
    executeReset   : BOOL;
    executeMove    : BOOL; 
    velFactor      : LREAL := 1; // adapt override factor if necessary(1 corresponds to 100 %)
    distance       : LREAL := ???; // ToDo: set to a reachable position 
    velocity       : LREAL := ???; // ToDo: set velocity for move

END_VAR

power(
        Axis            := axis,
        Enable          := enableAxis,
        EnablePositive  := enableAxis,
        EnableNegative  := enableAxis, 
        Status          => , 
        Error           => ,
        ErrorId         => );

setOverride(
        Axis            := axis,
        Enable          := enableOverride,
        VelocityFactor  := velFactor, 
        Enabled=> , 
        Error=> , 
        ErrorId=> );

stop(
        Axis            := axis,
        Execute         := executeStop, // The command is executed with a positive edge.
        Deceleration    := , // If the value is <= 0, the deceleration 
                             // parameterized with the last Move command is used.
        Jerk            := , // If the value is <= 0, the jerk parameterized 
                             // with the last Move command is used.
        Done            => ,
        Busy            => ,
        Active          => ,
        CommandAborted  => ,
        Error           => ,
        ErrorId         => );

reset(
        Axis            := axis,
        Execute         := executeReset, // The command is executed with a positive edge.
        Done            => ,
        Busy            => ,
        Error           => ,
        ErrorId         => );

moveRelative(
        Axis            := axis, 
        Execute         := executeMove, // The command is executed with a positive edge.
        Distance        := distance,
        Velocity        := velocity, 
        Acceleration    := LREAL_CONST.DEFAULT, // If the value is LREAL_CONST.DEFAULT, 
                             // the standard acceleration from the axis configuration is used.
        Deceleration    := LREAL_CONST.DEFAULT, // If the value is LREAL_CONST.DEFAULT, 
                             // the standard deceleration from the axis configuration is used.
        Jerk            := LREAL_CONST.DEFAULT, // If the value is LREAL_CONST.DEFAULT, 
                             // the standard jerk from the axis configuration is applied.
        BufferMode      := Tc3_Mc3Base.EBufferMode.Buffered, 
        Done            => ,
        Busy            => ,
        Active          => ,
        CommandAborted  => ,
        Error           => ,
        ErrorId         => );