Moving the axis via the PLC

Requirements

• A TwinCAT project with an MC project has been created;
  see Creating an MC project.
• A simulation axis was created in the MC project;
  see Create axis object.
• A PLC project was created in the TwinCAT project.

Including the PLC library

Writing a PLC program

All necessary data types and function blocks for a simple PLC motion program with MC3 are contained in the Tc3_Mc3Ptp library.

AXIS_REF

For each axis one instance of the data type AXIS_REF is required, which is the interface between PLC and MC3. It contains all the information about the axis that is given to the MC function blocks as a reference.

MC_Power

The MC_Power function block is used to enable the axis and specify its direction of motion.

MC_SetOverride

The MC_SetOverride function block can be used to change the axis's velocity override. By default, the factor is set to 1 (=100%), so changing the factor is optional.

MC_Reset

The function block MC_Reset can be used to reset an error on an axis.

MC_MoveRelative

The MC_MoveRelative function block can be used to move the axis by a specified distance.

Simple programming

PROGRAM MAIN
VAR
    axis           : AXIS_REF;
    power          : MC_Power;
    setOverride    : MC_SetOverride;
    moveRelative   : MC_MoveRelative;
    reset          : MC_Reset;
    stop           : MC_Stop;
    enableAxis     : BOOL;
    enableOverride : BOOL;
    executeStop    : BOOL;
    executeReset   : BOOL;
    executeMove    : BOOL; 
    velFactor      : LREAL := 1; // adapt override factor if necessary(1 corresponds to 100 %)
    distance       : LREAL := ???; // ToDo: set to a reachable position 
    velocity       : LREAL := ???; // ToDo: set velocity for move

END_VAR

power(
        Axis            := axis,
        Enable          := enableAxis,
        EnablePositive  := enableAxis,
        EnableNegative  := enableAxis, 
        Status          => , 
        Error           => ,
        ErrorId         => );

setOverride(
        Axis            := axis,
        Enable          := enableOverride,
        VelocityFactor  := velFactor, 
        Enabled=> , 
        Error=> , 
        ErrorId=> );

stop(
        Axis            := axis,
        Execute         := executeStop, // The command is executed with a positive edge.
        Deceleration    := , // If the value is <= 0, the deceleration 
                             // parameterized with the last Move command is used.
        Jerk            := , // If the value is <= 0, the jerk parameterized 
                             // with the last Move command is used.
        Done            => ,
        Busy            => ,
        Active          => ,
        CommandAborted  => ,
        Error           => ,
        ErrorId         => );

reset(
        Axis            := axis,
        Execute         := executeReset, // The command is executed with a positive edge.
        Done            => ,
        Busy            => ,
        Error           => ,
        ErrorId         => );

moveRelative(
        Axis            := axis, 
        Execute         := executeMove, // The command is executed with a positive edge.
        Distance        := distance,
        Velocity        := velocity, 
        Acceleration    := LREAL_CONST.DEFAULT, // If the value is LREAL_CONST.DEFAULT, 
                             // the standard acceleration from the axis configuration is used.
        Deceleration    := LREAL_CONST.DEFAULT, // If the value is LREAL_CONST.DEFAULT, 
                             // the standard deceleration from the axis configuration is used.
        Jerk            := LREAL_CONST.DEFAULT, // If the value is LREAL_CONST.DEFAULT, 
                             // the standard jerk from the axis configuration is applied.
        BufferMode      := Tc3_Mc3Base.EBufferMode.Buffered, 
        Done            => ,
        Busy            => ,
        Active          => ,
        CommandAborted  => ,
        Error           => ,
        ErrorId         => );