Messung Potentiometer

Das Potentiometer ist mit dem integrierten Netzteil (max. 5 V, einstellbar) zu versorgen. Die Schleifer-Spannung wird dann im Verhältnis zur Speisespannung gemessen und in % ausgegeben. Technisch verläuft die Messung also wie eine DMS‑Halbbrücke.

Im Folgenden ist die Spezifikation im 5-Leiter-Anschluss gegeben, externe Leitungswiderstände werden durch den 5-Leiter-Anschluss kompensiert und das Poti wird direkt vom Messkanal erfasst. Im 3-Leiter-Anschluss leistet der Messkanal grundsätzlich die gleiche Spezifikation, da er intern weiterhin im 5-Leiter-Betrieb misst. Allerdings müssen durch das angeschlossene Poti die zumeist unklaren und temperaturabhängigen Zuleitungs- und Übergangswiderstände in Kabeln und Steckern berücksichtigung finden, da sie die Messung beeinträchtigen. Das Gesamtsystem „Potentiometer + Zuleitungen + Messkanal“ im 3-Leiter-Anschluss wird daher die u.a. Spezifikationswerte praktisch nicht erreichen können.

Mögliche Diagnosen bei Vollausschlag bzw. 0-Anzeige:

• Schleiferbruch
• Versorgungsunterbrechung

Es sind Potentiometer ab 500 Ω einsetzbar.

Die Spezifikation wie auch der herstellerseitige Abgleich wurde an einem 5-kΩ-Potentiometer ermittelt. Bei einem anderen Potentiometer-Widerstand kommt es zu Fehlmessung durch die geänderten Parallelschaltungsverhältnisse, vgl. Kapitel „Speisung, Potentialgruppen“.

Die Verzerrung kann zudem mathematisch erfasst werden:

Abb.91: Unterschied zwischen 500 Ω und 5 kΩ Poti

Verwendung der Beispielprogramme Dieses Dokument enthält exemplarische Anwendungen unserer Produkte für bestimmte Einsatzbereiche. Die hier dargestellten Anwendungshinweise beruhen auf den typischen Eigenschaften unserer Produkte und haben ausschließlich Beispielcharakter. Die mit diesem Dokument vermittelten Hinweise beziehen sich ausdrücklich nicht auf spezifische Anwendungsfälle, daher liegt es in der Verantwortung des Anwenders zu prüfen und zu entscheiden, ob das Produkt für den Einsatz in einem bestimmten Anwendungsbereich geeignet ist. Wir übernehmen keine Gewährleistung, dass der in diesem Dokument enthaltene Quellcode vollständig und richtig ist. Wir behalten uns jederzeit eine Änderung der Inhalte dieses Dokuments vor und übernehmen keine Haftung für Irrtümer und fehlenden Angaben.

Zur theoretischen Korrektur eines anderen Potentiometers kann folgender Beispielcode eingesetzt werden:

VAR     

    R_Poti_calibration : LREAL := 5000.0; // Ohm (vendor calibration case)

    R_Poti_actual : LREAL := 500.0; // Ohm (user application case)

    Rin : LREAL := 2.06E6; // Ohm

    PDO : LREAL; // RAW Value 

    PDO_Ratio : LREAL;

    R2_act : LREAL;

    R1_act : LREAL;

    R2_act_Rin_parallel : LREAL;

    R2_calibration : LREAL;

    R1_calibration : LREAL;

    R2_calibration_Rin_parallel : LREAL;

    PDO_corrected : LREAL;

END_VAR

PDO_Ratio := PDO / 7812500.0;

R2_act := R_Poti_actual / 2.0 - PDO_Ratio * R_Poti_actual / 2.0;

R1_act := R_Poti_actual / 2.0 + PDO_Ratio * R_Poti_actual / 2.0;

IF (R2_act + Rin) <> 0 THEN

            R2_act_Rin_parallel := (R2_act * Rin) / (R2_act + Rin);

ELSE

            R2_act_Rin_parallel := 0.0;

END_IF

R2_calibration := R_Poti_calibration / 2.0 - PDO_Ratio * R_Poti_calibration / 2.0;

R1_calibration := R_Poti_calibration / 2.0 + PDO_Ratio * R_Poti_calibration / 2.0;

IF (R2_calibration + Rin) <> 0 THEN

            R2_calibration_Rin_parallel := (R2_calibration * Rin) / (R2_calibration + Rin);

ELSE

            R2_calibration_Rin_parallel := 0.0;

END_IF

IF (R1_act + R2_act_Rin_parallel) <> 0 AND R_Poti_actual <> 0 AND (R1_calibration + R2_calibration_Rin_parallel) <> 0 AND R_Poti_calibration <> 0 THEN

            PDO_corrected := (PDO_Ratio-

                        (((2.0*(0.5-R2_act_Rin_parallel/(R1_act+R2_act_Rin_parallel)))-

                        (2.0*(0.5-R2_act/R_Poti_actual)))-

                        ((2.0*(0.5-R2_calibration_Rin_parallel/(R1_calibration+R2_calibration_Rin_parallel)))-

                        (2.0*(0.5-R2_calibration/R_Poti_calibration)))))*7812500.0;

ELSE

            PDO_corrected := 0.0;

END_IF

¹) Gültig für ELM3504-00x0 ab HW04, ELM3502-00x0 ab HW03

ELM3502 (20 kSps)

ELM3504 (10 kSps)

Potentiometer-Messbereich

Abb.92: Darstellung Potentiometer-Messbereich