Cyclical data and time series databases

Declaration:

    State: E_DbLogState;
    bWriting: BOOL; // Set this bool fla to write the data once into the InfluxDB
    
    dbid: UDINT := 1; // Handle to the configured database
    
    QueryOption_TSDB_Insert : T_QueryOptionTimeSeriesDB_Insert; // defines detailed Queryparameter
    fbNoSQLQueryBuilder_TimeSeriesDB : FB_NoSQLQueryBuilder_TimeSeriesDB; // defines database type specific api
    fbNoSqlQueryEvt : FB_NoSQLQueryEvt(sNetID := '', tTimeout := T#15S); // functionblock to execute queries
    
    // databuffer for 1 second with 10 ms time delta
    windTurbineData: ARRAY[1..100] OF WindTurbineData;
    
    // error handling helper values
    TcResult: Tc3_Database.I_TcMessage;
    bError: BOOL;
    sErrorMessage: STRING(255);

    i: INT;
    rand : DRAND; 
    nrand: LREAL;

Declaring the data source structure:

In this structure the attributes "TagName" and "FieldName" are used to declare the data fields as tags or fields. By default they are declared as fields. These attributes can also be used if you want the column name in the table to differ from the symbol name in the PLC.

To capture unset data during data analysis, default values outside the value range can be used to detect such data during the analysis.

TYPE WindTurbineData :
STRUCT
    
    {attribute 'TagName' := 'ID'}
    WindTurbineID : STRING(255);
    
    {attribute 'FieldName' := 'Power'}
    Power : LREAL := -1; // [0) [kW]
    
    {attribute 'FieldName' := 'Wind Speed'}
    WindSpeed : LREAL := -1; // [0) [m/s]
    
    {attribute 'FieldName' := 'Wind Direction'}
    WindDirection : LREAL := -1; // [0,360][°]
    
END_STRUCT
END_TYPE
        

(WindTurbineData.tcDUT)

Declaration of the ENUM for the State-Machine:

TYPE E_DbLogState :
(
    idle := 0,
    init,
    writing,
    error
);
END_TYPE

Generating sample data:

        FOR i := 1 TO 100 BY 1 DO
             rand();
             nrand := rand.Num;
            windTurbineData[i].WindDirection := 240.328 + nrand;
            windTurbineData[i].WindSpeed := 7.3292 + nrand;
            windTurbineData[i].Power := 1133.1975 + nrand;
            windTurbineData[i].WindTurbineID := 'Wind Turbine Verl 13';
        END_FOR

CASE State OF
    
    E_DbLogState.idle:
        IF bWriting THEN
            bWriting := FALSE;
            State := E_DbLogState.init;
        END_IF

Preparing the call:

In this case, the array 'windTurbineData' is written into the 'WindMeasurement' table of the database. Therefore the data is read directly from the process image. The data type is specified to read the addresses in the memory. The time of the data sets is automatically generated by specifying the start time and the time interval. The data must be stored correctly in the array. For example, one data set in the array can be used per PLC cycle. It is useful to create a PLC task for this process. In this example the cycle time is 10 ms.

    E_DbLogState.init:
    
        fbNoSQLQueryBuilder_TimeSeriesDB.pQueryOptions := ADR(QueryOption_TSDB_Insert);
        fbNoSQLQueryBuilder_TimeSeriesDB.cbQueryOptions := SIZEOF(QueryOption_TSDB_Insert);    
        
        QueryOption_TSDB_Insert.sTableName := 'WindMeasurement';
        QueryOption_TSDB_Insert.sDataType := 'WindTurbineData';
        QueryOption_TSDB_Insert.pSymbol := ADR(windTurbineData);
        QueryOption_TSDB_Insert.cbSymbol := SIZEOF(windTurbineData);
        QueryOption_TSDB_Insert.nDataCount := 100;
        QueryOption_TSDB_Insert.nStartTimestamp := F_GetSystemTime();
        QueryOption_TSDB_Insert.nCycleTime := 10000; // (in 100 ns)
        State := E_DbLogState.writing;
        

Writing the data:

This call writes the data to the configured database with the corresponding database ID. This can take several cycles, since it is an asynchronous process. If necessary, several storage arrays must be used to ensure that the data is recorded seamlessly without gaps.

    E_DbLogState.writing:    
    
        IF fbNoSqlQueryEvt.Execute(dbid, fbNoSQLQueryBuilder_TimeSeriesDB) THEN
            IF fbNoSqlQueryEvt.bError THEN
                TcResult := fbNoSqlQueryEvt.ipTcResult;                
                State := E_DbLogState.error;
            ELSE
                State := E_DbLogState.idle;
            END_IF
        END_IF
        

Error handling:

Use the Tc3 Eventlogger for error handling

    E_DbLogState.error:
        
        IF TcResult.RequestEventText(1033, sErrorMessage, SIZEOF(sErrorMessage)) THEN
            TcResult.Send(F_GetSystemTime());
            State := E_DbLogState.idle;
            bError := TRUE;
        END_IF
        
        
END_CASE