Calling the generated module from a PLC project

Configuration in Simulink

In the settings under Tc Advanced, CallBy is initially set to Module (can be changed later in TwinCAT Engineering).

The parameter Skip caller verification is visible from TE1400 version 1.2.1230.

The parameter PLC Function Block (TcCOM wrapper) is available from TE1400 version 1.2.1216.0:

The following options are available for selection:

The module-specific function block

FB_<ModuleName> is derived from FB_TcMatSimObject and provides the methods and properties described above. In addition, the following properties are implemented:

Public Properties:

Notes regarding FB with properties for all parameters

If Process image is set to Internal DataArea under Tc Interfaces in the Parameter access area, a property is created for all parameters. These must then be read and written as an entity:

PROGRAM MAIN
VAR
    // declare function block (details see below)
    fbControl : FB_TctSmplTempCtrl(oid := 16#01010010);
    // local PLC variable
    ModelParameters : P_TctSmplTempCtrl_T;
END_VAR

// read all model parameters
ModelParameters := fbControl.ModelParameters_Online;
// change value
ModelParameters.Kp := 20;
// write all model parameters
fbControl.ModelParameters_Online := ModelParameters;

If Process image is set to No DataArea under Tc Interfaces in the Parameter access area, a separate property is created for each model parameter. These can then be read and written directly without a local PLC variable.

Fb<ModelName>.ModelParameters_<ParameterName>_Online

Referencing a static module instance:

The FB can be used to access module instances previously created in the XAE, e.g. under System > TcCOM Objects. For this static case, the object ID of the corresponding module instance must be transferred during declaration of the FB instance:

fbStatic : FB_<ModuleName>(oid:=<ObjectId>);

The object ID can be found in the instance of TcCOM under the Object tab.

Sample code

The following code sample illustrates the application of a module-specific function block in a simple PLC program in ST code, using an object of module class "TempContr" with ObjectID 0x01010010 as an example:

PROGRAM MAIN
VAR
    // declare function block with ID of referenced Object
    fbTempContr : FB_TempContr(oid:= 16#01010010 );
    // input process image variable
    nInputTemperature AT%I* : INT;
    // output process image variable
    bHeaterOn AT%Q* : BOOL;
END_VAR
IF (fbTempContr.State = TCOM_STATE.TCOM_STATE_OP) THEN
    // set input values
    fbTempContr.stInput.FeedbackTemp := nInputTemperature;
    // execute module code
    fbTempContr.Execute();
    // get output values
    bHeaterOn := fbTempContr.stOutput.HeaterOn;
END_IF

Generating and referencing a dynamic module instance:

If <ObjectId> = 0, the FB attempts to generate an instance of the TcCom module dynamically:

fbDynamic : FB_<ModuleName>(oid:=0);

In this case, the module instance does not appear in the XAE configuration tree, but only appears at runtime (i.e. after the initialization of the PLC instance) in the "Project Objects" table of the System > TcCOM Objects node.

A prerequisite for dynamic instantiation of a TcCOMmodule if that the corresponding "Class Factory" is loaded. To this end, the Load checkbox (or the TC Loader checkbox if the "TwinCAT Loader" is used) must be set for the "Class Factory" of the module under the Class Factories tab of the System > TcCOM Objects node. The name of the "Class Factory" of a TcCOM module generated from Simulink usually matches the module name, although the ClassFactory name is limited to fewer characters.

A further condition for dynamic instantiation of a module is adequate availability of dynamic memory. To this end, the ADS router memory must be set to an adequate size.
Sample code:

PROGRAM MAIN
VAR
    // declare function block
    fbTempContr_Dyn : FB_TempContr(oid:= 0 );
    // input process image variable
    nInputTemperature AT%I* : INT;
    // output process image variable
    bHeaterOn AT%Q* : BOOL;
    // reset error code and reinitialize Object
    bReset: BOOL;
    // initialization helpers
    stInitData : ST_TempContr_InitData;
    bInitialized : BOOL;
END_VAR
IF (NOT bInitialized) THEN
    stInitData := fbTempContr_Dyn.InitData; // read default parameters
    // adapt required parameters:
    stInitData.ContextInfoArr_0_TaskOid := 16#02010020;    // oid of the plc task
    stInitData.ContextInfoArr_0_TaskCycleTimeNs := 10 * 1000000; // plc task cycle time in ns
    stInitData.ContextInfoArr_0_TaskPriority := 20; // plc task priority
    stInitData.CallBy := TctModuleCallByType.Module;
    stInitData.StepSize := TctStepSizeType.UseTaskCycleTime; 
    // set init data, copied to module the next time it switches from INIT to PREOP:
    fbTempContr_Dyn.InitData := stInitData;
    bInitialized := TRUE;
ELSIF (fbTempContr_Dyn.State<TCOM_STATE.TCOM_STATE_OP) THEN
    // try to change to OP mode
    fbTempContr_Dyn.State := TCOM_STATE.TCOM_STATE_OP;
ELSIF (NOT fbTempContr_Dyn.Error) THEN
    // set input values
    fbTempContr_Dyn.stInput.FeedbackTemp := nInputTemperature;
    // execute module code
    fbTempContr_Dyn.Execute();
    // get output values
    bHeaterOn := fbTempContr_Dyn.stOutput.HeaterOn;
END_IF

IF (bReset) THEN
    IF (fbTempContr_Dyn.Error) THEN
        fbTempContr_Dyn.ResetHresult();
    END_IF
    fbTempContr_Dyn.State := TCOM_STATE.TCOM_STATE_INIT;
END_IF

Import of several PLCopen-XML: FB_TcMatSimObject

The generic function block FB_TcMatSimObject is identical for all modules generated with TE1400 (from V1.2.12016.0). Even if it is used for different modules, it only has to be imported once into the PLC project.

Description of the function block:

Public Methods

Public Properties

Referencing a module instance

Just like the module-specific FB derived from it, FB_TcMatSimObject can be instantiated with the object ID of a static module instance or with 0:

fbStatic : FB_TcMatSimObject(oid:=<ObjectId>); // Referenz auf statisches TcCom-Objekt 

fbDynamic : FB_TcMatSimObject(oid:=0); // Erzeugen eines dynamisches TcCom-Objektes