Camming

Corefunction wird nicht von Umrichterachsen unterstützt Diese Corefunction wird von Umrichterachsen nicht unterstützt. Jede Verwendung wird DEVICE_NOTINIT melden und eine Fehlermeldung auslösen.

Die Eigenschaft bietet zwei Optionen: Camming.Pos für Position-Camming und Camming.Velo für Geschwindigkeit-Camming. Dazu werden zwei Klassen desselben Typs instanziiert, jedoch mit unterschiedlichen Parametrierungen.

Alle diese Funktionen gehören zu der Gruppe der statisch gesteuerten Corefunctions.

Beide Camming-Arten verwenden einen Vorgabewert, um einen Stellwert innerhalb einer Camming-Stützstellentabelle zu identifizieren. Für weitere Informationen siehe CammingLookUp.

Als Vorgabewert können alle sinnvollen Informationen dienen. Übliche Optionen sind eine Zeit (LREAL-Variable, die mit Null beginnt und zyklisch durch Addition der Zykluszeit der SPS-Tasks aktualisiert wird) oder die Position einer anderen Achse.

Die Verwendung von Camming erfordert mehrere Schritte:

• Es muss eine Camming-Stützstellentabelle instanziiert werden. Für die Anzahl dieser Tabellen gibt es keine Regel. Eine einmal verwendete Tabelle kann zu einem späteren Zeitpunkt erneut verwendet werden, indem die folgenden Schritte wiederholt werden.
• Die Tabelle muss durch Laden der Tabellenpunkte definiert werden. Vergewissern Sie sich, dass die Punktdaten der Camming-Art (Position, Geschwindigkeit) entsprechen, für die sie verwendet werden sollen.
• Die Eigenschaften der Tabelle müssen aktualisiert werden.
• Die Tabelle muss dem Camming mit der Methode SetLookupinterface() zugewiesen werden. Zu diesem Zeitpunkt darf das Camming nicht kommandiert sein.
• Ein erster Vorgabewert muss mit der Methode SetGuidingValue() angegeben werden.
• Verwenden Sie zum richtigen Zeitpunkt DoCamming(TRUE), um die Funktion zu aktivieren. Stellen Sie sicher, dass sich die Achse in einer Situation (Position, Geschwindigkeit) befindet, die mit der Situation der Camming-Tabelle übereinstimmt.
• Achten Sie auf eine zyklische Aktualisierung des Vorgabewerts.
• Verwenden Sie zum richtigen Zeitpunkt DoCamming(FALSE), um die Funktion zu deaktivieren. Achten Sie auf die Situation (Position, Geschwindigkeit) der Achse.

FUNCTION_BLOCK FB_Camming EXTENDS FB_CorefunctionFeedback

// For this example, the axis should currently be in the fCenter position
CASE nState OF
0:  // Define camming curve
    fCenter := 100.0;       // [mm]
    fAmplitude := 100.0;    // [mm]
    fCycleTime := 0.002;    // [s]
    
    // parameterise the lookup table
    fbCammingLookup.Equidistance := TRUE;
    fbCammingLookup.Interpolation := E_LookupMode.eSecondOrder;
    fbCammingLookup.SetPoints(401);
    fbCammingLookUp.MinGuidingValue := 0.0;
    fbCammingLookUp.MaxGuidingValue := 15.0;

    // Create a sinusoidal curve over 15 seconds 
    FOR i := 1 TO 401 DO
        fCamTime := 15.0 * (i - 1) / 400.0;
        fPoint := fCenter + fAmplitude * SIN(2.0 * PI * fCamTime / 15.0);
        IF FAILED(fbCammingLookUp.SetPoint(i, fPoint, 35.0)) THEN
            nState := -1;
        END_IF;
    END_FOR
    
    // check table validation
    IF NOT fbCammingLookup.Valid THEN
        nState := -1;
        
    // assign camming table to camming function
    ELSIF FAILED(iAxisBase.Camming.Pos.SetLookupInterface(fbCammingLookUp)) THEN
        nState := -1;
        
    // assign initial camming value
    ELSIF FAILED(iAxisBase.Camming.Pos.SetGuidingValue(0.0)) THEN
        nState := -1;
    END_IF
    
    IF nState >= 0 THEN
        nState := nState + 1;
    END_IF

1:  // start camming
    IF FAILED(iAxisBase.Camming.Pos.DoCamming(TRUE)) THEN
        nState := -1;
    END_IF
    
    fTime := 0.0;
            
    IF nState > 0 THEN
        nState := nState + 1;
    END_IF
    
2:  // operate camming
    fTime := MIN(fTime + fCycleTime, 15.0);
    
    IF iAxisBase.Camming.Pos.FailedState THEN
        nState := -1;
    ELSIF FAILED(iAxisBase.Camming.Pos.SetGuidingValue(fTime)) THEN
        nState := -1;
    ELSIF fTime >= 15.0 THEN
        nState := nState + 1;;
    END_IF

3,  // camming done
-1: // error

    fTime := 0.0;
    iAxisBase.Camming.Pos.DoCamming(FALSE);

END_CASE