Camming

Die Eigenschaft bietet zwei Optionen: Camming.Pos für Position-Camming und Camming.Velo für Geschwindigkeit-Camming. Dazu werden zwei Klassen desselben Typs instanziiert, jedoch mit unterschiedlicher Parametrierung.

Beide Camming-Arten verwenden eine Führungsgröße, um einen Stellwert innerhalb einer Camming-Stützstellentabelle zu identifizieren. Für weitere Informationen siehe CammingLookUp.

Als Führungsgröße können alle sinnvollen Informationen dienen. Übliche Optionen sind eine Zeit (LREAL-Variable, die mit 0 beginnt und zyklisch durch Addition der Zykluszeit der SPS-Tasks aktualisiert wird) oder die Position einer anderen Achse.

Die Verwendung von Camming erfordert mehrere Schritte:

• Die Camming-Stützstellentabelle muss initialisiert werden. Sofern sie die interne Tabelle verwenden (empfohlen), müssen Sie mindestens die Interpolationsart vorgeben und die Anzahl an Punkten der Tabelle definieren. Ein Beispiel zur Initialisierung finden Sie oder im Beispiel weiter unten.
• Die Tabelle muss durch Vorgabe aller Tabellenpunkte definiert werden. Vergewissern Sie sich, dass die Punktdaten der Camming-Art (Position, Geschwindigkeit) entsprechen, für die sie verwendet werden sollen.
• Im Falle von äquidistanten Punkten muss der Tabelle zusätzlich ein Minimal- und Maximalwert für den GuidingValue zugewiesen werden.
• Eine initiale Führungsgröße sollte vor der Aktivierung des Cammings mittels der Eigenschaft GuidingValue vorgegeben werden.
• Verwenden Sie zum richtigen Zeitpunkt DoCamming(TRUE), um die Funktion zu aktivieren. Stellen Sie sicher, dass sich die Achse in einem Zustand (Position, Geschwindigkeit) befindet, der mit der Führungsgröße der Camming-Tabelle übereinstimmt.
• Achten Sie auf eine zyklische Aktualisierung der Führungsgröße.
• Verwenden Sie zum richtigen Zeitpunkt DoCamming(FALSE), um die Funktion zu deaktivieren. Achten Sie auf den Zustand (Position, Geschwindigkeit) der Achse.

FUNCTION_BLOCK FB_Camming EXTENDS FB_CorefunctionFeedback

¹ Obsolete

// For this example, the axis should currently be in the fCenter position
CASE nState OF
0:  // Define camming curve
    fCenter := 100.0;       // [mm]
    fAmplitude := 100.0;    // [mm]
    fCycleTime := 0.002;    // [s]
    
    // parameterise the lookup table
    iAxisBase.Camming.Pos.LookUp.Equidistance := TRUE;
    iAxisBase.Camming.Pos.LookUp.Interpolation := E_LookupMode.eSecondOrder;
    iAxisBase.Camming.Pos.LookUp.SetPoints(401);
    iAxisBase.Camming.Pos.LookUp.MinGuidingValue := 0.0;
    iAxisBase.Camming.Pos.LookUp.MaxGuidingValue := 15.0;

    // Create a sinusoidal curve over 15 seconds 
    FOR i := 1 TO 401 DO
        fCamTime := 15.0 * (i - 1) / 400.0;
        fPoint := fCenter + fAmplitude * SIN(2.0 * PI * fCamTime / 15.0);
        IF FAILED(iAxisBase.Camming.Pos.LookUp.SetPoint(i, fPoint, 35.0)) THEN
            nState := -1;
        END_IF;
    END_FOR
    
    // check table validation
    IF NOT iAxisBase.Camming.Pos.LookUp.Valid THEN
        nState := -1;
    END_IF

    // assign initial camming value
    iAxisBase.Camming.Pos.GuidingValue := 0.0;
    fTime := 0.0;
    
    IF nState >= 0 THEN
        nState := nState + 1;
    END_IF

1:  // start camming
    IF FAILED(iAxisBase.Camming.Pos.DoCamming(TRUE)) THEN
        nState := -1;
    END_IF
    
    IF nState > 0 THEN
        nState := nState + 1;
    END_IF
    
2:  // operate camming
    fTime := MIN(fTime + fCycleTime, 15.0);
    
    iAxisBase.Camming.Pos.GuidingValue := fTime;
    
    IF iAxisBase.Camming.Pos.FailedState THEN
        nState := -1;
    ELSIF fTime >= 15.0 THEN
        nState := nState + 1;;
    END_IF

3,  // camming done
-1: // error

    fTime := 0.0;
    iAxisBase.Camming.Pos.DoCamming(FALSE);

END_CASE