Beispiel „Planar-Tracks zu Netzwerk verbinden“
Anhand dieser Anleitung werden Sie ein TwinCAT-Projekt anlegen, das vier Planar-Tracks zu einem Netzwerk verbindet.
Planar-Track anlegen
- 1. Fügen Sie vier Planar-Tracks über Groups > Add New Item… hinzu, siehe Konfiguration.
PLC anlegen
- Siehe Vorabschritte PLC anlegen.
- 1. Legen Sie über MAIN die gewünschte Anzahl an Movern („MC_PlanarMover“) und Tracks („MC_PlanarTrack“) an.
- Diese repräsentieren Mover und Tracks in der MC Configuration.
- 2. Legen Sie, wie nachfolgend gezeigt, vier Tracks sowie eine Zustandsvariable für eine Zustandsmaschine und zwei Hilfspositionen für die Tracks an.
PROGRAM MAIN
VAR
track_one, track_two, track_three, track_four : MC_PlanarTrack;
state : UDINT;
pos1, pos2 : PositionXYC;
END_VAR- 3. Programmieren Sie anschließend in der MAIN einen Ablauf.
- Dieser Programmcode erstellt und aktiviert vier Tracks, die zu einem Netzwerk verbunden sind, wie in obiger Abbildung gezeigt. Die sogenannten „Verschleifungen“ (siehe Geometrische Definition), also alle nicht-linearen Stücke der Tracks in diesem Beispiel, werden hier automatisch generiert. Sie geben nur die geraden Teilstücke vor.
CASE state OF
0:
pos1.SetValuesXY(250, 120);
pos2.SetValuesXY(650, 120);
track_one.AppendLine(0, pos1, pos2);
pos1.SetValuesXY(700, 170);
pos2.SetValuesXY(800, 450);
track_one.AppendLine(0, pos1, pos2);
pos1.SetValuesXY(650, 500);
pos2.SetValuesXY(250, 500);
track_one.AppendLine(0, pos1, pos2);
state := 1;
1:
pos1.SetValuesXY(200, 450);
pos2.SetValuesXY(200, 170);
track_two.StartFromTrack(0,track_one);
track_two.AppendLine(0, pos1, pos2);
track_two.EndAtTrack(0,track_one);
state := 2;
2:
pos1.SetValuesXY(200, 500);
pos2.SetValuesXY(120, 500);
track_three.StartFromTrack(0,track_one);
track_three.AppendLine(0, pos1, pos2);
state := 3;
3:
pos1.SetValuesXY(200, 550);
pos2.SetValuesXY(200, 750);
track_four.StartFromTrack(0,track_one);
track_four.AppendLine(0, pos1, pos2);
state := 4;
4:
track_one.Enable(0);
track_two.Enable(0);
track_three.Enable(0);
track_four.Enable(0);
state := 5;
5:
IF track_one.MCTOPLC_STD.State = MC_PLANAR_STATE.Enabled AND
track_two.MCTOPLC_STD.State = MC_PLANAR_STATE.Enabled AND
track_three.MCTOPLC_STD.State = MC_PLANAR_STATE.Enabled AND
track_four.MCTOPLC_STD.State = MC_PLANAR_STATE.Enabled THEN
state := 6;
END_IF
END_CASE | Tracks müssen an allen Punkten C2-stetig sein. Das heißt, dass ihre Positionen, Richtungen, sowie Krümmungen nahtlos ineinander übergehen müssen. Die automatisch generierten Verschleifungen berücksichtigen diese Vorgabe, siehe Geometrische Definition. Auch wenn die Eckstücke wie Viertelkreise aussehen, sind sie keine, da Kreise an jedem Punkt eine positive (konstante) Krümmung haben und Geraden die Krümmung Null aufweisen. |
Befehl abschicken
- 4. Um den Befehl auch abzuschicken, müssen Sie die Tracks nach dem END_CASE zyklisch mit ihrer Update-Methode triggern:
track_one.Update();
track_two.Update();
track_three.Update();
track_four.Update();Durch das Bauen der PLC werden Symbole des „PLC-Movers" und „-Tracks“ erzeugt, welche anschließend mit der Mover- bzw. Track-Instanz im MC-Projekt verknüpft werden können.
- 1. Verwenden Sie zum Bauen den Pfad PLC > Untitled1 > Untitled1 Project > Build.
- Die Tracks müssen jeweils separat über die folgenden Dialogfenster verlinkt werden.
Projekt aktivieren und starten
- 1. Aktivieren Sie die Konfiguration über den Button in der Menüleiste
. - 2. Versetzen Sie das TwinCAT-System in den Zustand „Run“ über den Button
. - 3. Loggen Sie die PLC über den Button in der Menüleiste ein
. - 4. Starten Sie die PLC über den Play-Button in der Menüleiste.
Das Track-Netzwerk ist am Ende des Zustandsautomaten (state = 6) fertig erstellt.
Die Länge der Tracks steht jeweils in den Online-Parametern der TCOM-Objekte im MC Project.
