FB_init

Expliziter Aufruf von FB_init

Expliziter Aufruf nicht empfohlen Bei den Methoden FB_init, FB_reinit und FB_exit handelt es sich um Systemfunktionen, die zu unterschiedlichen Zeitpunkten implizit aufgerufen werden (weitere Informationen hierzu finden Sie unter Betriebsfälle). Ein expliziter Aufruf dieser Methoden kann unbeabsichtigte Folgen haben und wird daher nicht empfohlen.

Die Methode FB_init kann prinzipiell auch explizit aufgerufen werden. Dies wird jedoch nicht empfohlen.

Bei einem expliziten Aufruf wird nicht nur der explizite Initialisierungscode der FB_init-Methode erneut ausgeführt, sondern auch die implizite Initialisierung findet erneut statt. Es werden z. B. alle Variablen neu initialisiert, sowohl bei automatischer Nullinitialisierung als auch bei individueller Werteinitialisierung.

Letzteres bewirkt, dass beide Initialisierungsschritte auch für die in dieser Instanz deklarierten FB-Instanzen durchgeführt werden. Dieser Vorgang setzt sich über die weiteren enthaltenen Instanzebenen fort.

Wenn FB-Instanzen neu initialisiert werden, ohne vorher de-initialisiert worden zu sein, kann dies zu Problemen im weiteren Programmablauf führen, beispielsweise wenn die FB_init-Methode dynamische Speicherallokationen oder einen Instanzzähler beinhaltet.

Da die FBs dabei nicht entsprechend ihrer vorgesehenen Verwendung genutzt werden und da die problematischen Folgen möglicherweise nicht abzuschätzen sind, wird ausdrücklich davon abgeraten, FB_init-Methoden explizit aufzurufen.

Schnittstelle der Methode FB_init

METHOD FB_init : BOOL
VAR_INPUT
    bInitRetains : BOOL; // if TRUE, the retain variables are initialized (warm start / cold start)
    bInCopyCode  : BOOL; // if TRUE, the instance afterwards gets moved into the copy code (online change)
END_VAR

Durch die Auswertung der FB_init-Methodenparameter können Sie die Betriebsfälle unterscheiden und die Implementierung gegebenenfalls anpassen. (Siehe Betriebsfälle)

Sie können in einer FB_init-Methode zusätzliche Methodeneingänge deklarieren. Diese Eingänge müssen Sie dann in der Deklaration der Funktionsbausteininstanz setzen.

FB_init bei abgeleiteten Bausteinen

Wenn ein Funktionsbaustein von einem anderen Funktionsbaustein abgeleitet ist, dann wird für diesen Funktionsbaustein automatisch die FB_init-Methode des Basisfunktionsbausteins ausgeführt. Falls die FB_init-Methode des abgeleiteten Funktionsbausteins explizit hinzugefügt wird, wird diese im Anschluss an die FB_init-Methode des Basisfunktionsbausteins ausgeführt (siehe Verhalten bei abgeleiteten Bausteinen).

Wenn die FB_init-Methode des abgeleiteten Funktionsbausteins in expliziter Form vorhanden sein soll, muss diese dieselben Parameter definieren wie die FB_init-Methode des Basisfunktionsbausteins. Sie können jedoch weitere Parameter hinzufügen, um für die abgeleitete Instanz eine spezielle Initialisierung einzurichten.

Beispiele für die Zuweisung von zusätzlichen FB_init-Parametern

Beispiel 1:

Methode FB_SerialDevice.FB_init

METHOD PUBLIC FB_init : BOOL
VAR_INPUT
    bInitRetains : BOOL; // if TRUE, the retain variables are initialized (warm start / cold start)
    bInCopyCode  : BOOL; // if TRUE, the instance afterwards gets moved into the copy code (online change)
    nComNum      : INT;  // additional input: number of the COM-interface that is to be observed
END_VAR

Deklaration des Funktionsbausteins FB_SerialDevice:

fbCom1  : FB_SerialDevice(nComNum := 1);
fbCom0  : FB_SerialDevice(nComNum := 0);

Beispiel 2:

Funktionsbaustein FB_Sample:

FUNCTION_BLOCK FB_Sample
VAR
    nStartValue : INT;
END_VAR

Methode FB_Sample.FB_init:

METHOD FB_init : BOOL
VAR_INPUT
    bInitRetains : BOOL; // if TRUE, the retain variables are initialized (warm start / cold start)
    bInCopyCode  : BOOL; // if TRUE, the instance afterwards gets moved into the copy code (online change)
    nValue       : INT;  // parameter to initialize the start value
END_VAR

nStartValue := nValue;

Deklaration des Funktionsbausteins FB_Sample:

PROGRAM MAIN
VAR
    fbSample1 : FB_Sample(123); // => fbSample1.nStartValue is set to 123
    fbSample2 : FB_Sample(456); // => fbSample2.nStartValue is set to 456
END_VAR

Beispiel 3:

FUNCTION_BLOCK FB_Sample
VAR_INPUT
    nInput           : INT;
END_VAR
VAR
    nLocalInitParam  : INT;
    nLocalProp       : INT;
END_VAR

METHOD FB_init : BOOL
VAR_INPUT
    bInitRetains : BOOL;  // if TRUE, the retain variables are initialized (warm start / cold start)
    bInCopyCode  : BOOL;  // if TRUE, the instance afterwards gets moved into the copy code (online change)
    nInitParam   : INT;
END_VAR

nLocalInitParam := nInitParam;

PROPERTY nMyProperty : INT

nLocalProp := nMyProperty;

PROGRAM MAIN
VAR
    fbSample  : FB_Sample(nInitParam := 1) := (nInput := 2, nMyProperty := 3);
    aSample   : ARRAY[1..2] OF FB_Sample[(nInitParam := 4), (nInitParam := 7)]
                            := [(nInput := 5, nMyProperty := 6), (nInput := 8, nMyProperty := 9)];
END_VAR