Writing CSV files

High-performance writing to the CSV file

The most efficient way to write to a CSV file is based on the function block FB_PLCDBCmdEvt. To this end, the link to the CSV file must be set in ASCII-DB 3.0 format. The DBValueType is irrelevant here. A table structure does not have to be defined in advance.

Sample:

The following structure is used as an example:

TYPE ST_CSVDataStruct :
STRUCT
    ID: LINT;
    Timestamp: DT;
    Name: STRING(80);
    Velocity: LREAL;
    Temperature: LREAL;
END_STRUCT
END_TYPE

The function block is initialized as follows:

VAR
    InputData: ST_CSVDataStruct;
    fbPLCDBCmd: FB_PLCDBCmd (sNetID:= '', tTimeout := T#30S);

    sCmd : T_MaxString := '{ID};{Timestamp};{Name};{Velocity};{Temperature}';

    para : ARRAY [0..4] OF ST_ExpParameter :=[
            (eParaType:= E_ExpParameterType.Int64, nParaSize := 8, sParaName := 'ID'),
            (eParaType:= E_ExpParameterType.DateTime, nParaSize := 4, sParaName := 'Timestamp'),
            (eParaType:= E_ExpParameterType.STRING_, nParaSize := 81, sParaName := 'Name'),
            (eParaType:= E_ExpParameterType.Double64, nParaSize := 8, sParaName := 'Velocity'),
            (eParaType:= E_ExpParameterType.Double64, nParaSize := 8, sParaName := 'Temperature')];
END_VAR

The individual parameters are specified in curly brackets within the command. Information about the type, byte length and name is assigned via the initialization. The name is used to recognize the parameter in the command and to replace it with the value from the PLC when it is written to the file.

The call in the PLC source code of the function block consists of a call:

IF fbPLCDBCmd.Execute(
    hDBID:= 3, 
    pExpression:= ADR(sCmd),
    cbExpression:= SIZEOF(sCmd),
    pData:= ADR(InputData),
    cbData:= SIZEOF(InputData) ,
    pParameter:= ADR(para),
    cbParameter:=SIZEOF(para)) 
THEN
    ;//Place for errorhandling or reactions;
END_IF

// Result: 16160;19-10-2018 12:27:38;Water Turbine;35.2238040741592;62.6461585412374

The hDBID depends on its configuration and can be taken from the database link. pData (or cbData) can be the address for the individual structure or for an array of its structure. This can lead to further performance improvements.

Structured writing and reading of a CSV file

Not all function blocks are possible with the ASCII format 3.0. Some functions of the TwinCAT Database Server require a preconfigured table structure. However, this cannot be stored in ASCII format 3.0. In this sample, a fixed structure is used to write and read the data with the PLCDBWriteEvt and PLCDBReadEvt function blocks in any structure.

The following structure is used as an example:

Export for the PLC under the 'Select' tab is also possible:

TYPE ST_CSVDataStruct :
STRUCT
    ID: LINT;
    Timestamp: DT;
    Name: STRING(80);
    Velocity: LREAL;
    Temperature: LREAL;
END_STRUCT
END_TYPE

The Write/ReadStruct methods of the respective PLC function blocks are used for any table structures:

VAR
    fbPLCDBWrite: FB_PLCDBWrite(sNetID:= '', tTimeout := T#30S);
    fbPLCDBRead : FB_PLCDBRead(sNetID:= '', tTimeout := T#30S);
    ColumnNames : ARRAY [0..4] OF STRING(50) := ['ID','Timestamp','Name','Velocity','Temperature'];
    Data: ST_CSVDataStruct;
    ReadData: ARRAY[0..4] OF ST_CSVDataStruct;
END_VAR

IF fbPLCDBWrite.WriteStruct(
    hDBID:= hDBID, 
    sTableName:= 'CSV_Sample', 
    pRecord:= ADR(Data), 
    cbRecord:= SIZEOF(Data), 
    pColumnNames:= ADR(ColumnNames), 
    cbColumnNames:= SIZEOF(ColumnNames) )
THEN
    ;//Place for errorhandling or reactions
END_IF

IF fbPLCDBRead.ReadStruct(
    hDBID:= hDBID, 
    sTableName:= 'CSV_Sample', 
    pColumnNames:= ADR(ColumnNames), 
    cbColumnNames:= SIZEOF(ColumnNames) , 
    sOrderByColumn:= 'ID', 
    eOrderType := E_OrderType.ASC, 
    nStartIndex:= 0, 
    nRecordCount:= 5, 
    pData:= ADR(ReadData), 
    cbData:=SIZEOF(ReadData))
THEN
    ;//Place for errorhandling or reactions
END_IF

The WriteStruct(...) method writes the Data structure to the database. The structures of the PLC and the CSV file are compared based on the ColumnNames.

The ReadStruct(...) method reads a certain number (nRecordCount) of records from the CSV file. These may be sorted based on a selected column. The size of the ReadData target array should be sufficient to receive all the retrieved data.