Erstellen einer strukturierten Ansicht (AKS)

Ein AKS (Anlagen-Kennzeichnungs-System) wird verwendet, um zu BACnet-Objekten zu navigieren, indem die Anlagenansicht und nicht die technologische Ansicht verwendet wird. Ein Facility Manager weiß, in welchem Gebäude, Stockwerk, Raum usw. sich ein BACnet-Objekt befindet.

Es ist eine gute Praxis, eine Kurzform für das AKS in die Objektnamen-Eigenschaft der BACnet-Objekte und eine (wahrscheinlich längere) Information in die Beschreibungseigenschaft zu setzen. Zusätzlich kann der Objekttyp Strukturierte Ansicht (FB_BACnet_View) verwendet werden, um die Benutzeransicht der Anlagenhierarchie bereitzustellen.

Der folgende Code veranschaulicht, wie man eine Navigation mit dem Operator '\/' (Backslash und Slash) erstellt. Dieser Operator kann den folgenden Eigenschaften (Typ Zeichenkette) zugeordnet werden:

Objektname

Description

Ereignismeldungstext

Zur Laufzeit wird das Trennzeichen durch die im Abschnitt Global / BACnet_Param angegebenen Zeichen ersetzt.

Codebeispiel für die Erstellung einer AKS-Struktur

PROGRAM MAIN
VAR
    fbDPADFirstLevel : FB_BACnet_View := (
        eNodeType := E_BACnet_NodeType.eArea,
        sObjectName := '\/A',
        sDescription := '\/Facilities');

    fbDPADSecondLevel : FB_BACnet_View := (
        iParent := fbDPADFirstLevel,
        eNodeType := E_BACnet_NodeType.eOrganizational,
        sObjectName := '\/B',
        sDescription := '\/Building');

    fbDPADThirdLevel : FB_BACnet_View := (
        iParent := fbDPADSecondLevel,
        eNodeType := E_BACnet_NodeType.eNetwork,
        sObjectName := '\/C',
        sDescription := '\/Floor');

    fbAi : FB_BACnet_AI := (
        iParent := fbDPADThirdLevel,
        sObjectName := '\/ObjectName',
        sDescription := '\/Description',
        sDeviceType := 'TemperatureSensor',
        eUnit := E_BA_Unit.eTemperature_DegreesCelsius,
        fMinPresValue := -50.0,
        fMaxPresValue := 150.0,
        fHighLimit := 100,
        fLowLimit := -25,
        bHighLimitEnable := TRUE,
        bLowLimitEnable := TRUE,
        nNotificationClass := 10,
        aEventEnable := [ TRUE, TRUE, FALSE ],
        aEventMessageTextsConfig := [ '\/Alarm', '\/Fault', '\/Normal' ]);
END_VAR
------------------------------------------------------------------
fbDPADFirstLevel();
fbDPADSecondLevel();
fbDPADThirdLevel();
fbAi();

Dieser Code erzeugt drei Structured-View-Objekte und ein Analog-Input-Objekt und verbindet das AKS über die iParent-Elemente, die auf den aufrufenden Funktionsbaustein verweisen.

Die Auswahl, wie die Tree Items im System Manager angezeigt werden, kann in den Global Params der Bibliotheksinstanz festgelegt werden:

eSymbolName: Der Symbolname aus der SPS wird als Tree Item Name verwendet.

eObjectName: Der BACnet-Objektname wird als Tree Item Name verwendet.

eDescription: Die BACnet-Beschreibung wird als Tree Item Name verwendet.

Der Baum des System Managers sieht wie folgt aus (im folgenden Beispiel wurde der Objektname verwendet):

Die Trennzeichen, die für die drei Eigenschaften verwendet werden, die möglicherweise ein AKS enthalten (Objektname, Beschreibung und Ereignismeldungstexte), können in der Einstellung Global Params der Bibliothek individuell festgelegt werden.