Anlegen der Beispielprojekte

Das TwinCAT-Projekt Measuring

Gehen Sie folgendermaßen vor, um das Measuring Projekt in TwinCAT anzulegen:

In dem neuen Projekt müssen nun das EAP Gerät und ein PLC Projekt angelegt werden.

PLC Projekt Measuring

Das Schreiben eines SPS Programms erfolgt innerhalb eines TwinCAT PLC Projekts. Legen Sie also ein PLC Projekt anhand der folgenden Schritte an:

Ein Standard PLC Projekt referenziert bereits auf ein paar grundlegende PLC Bibliotheken. Für das kommende Beispielprogramm wird noch die Bibliothek Tc2_Utilities benötigt. Fügen Sie eine Referenz auf diese Bibliothek folgendermaßen hinzu:

Das Measuring SPS Beispielprogramm

Das Measuring Beispielprogramm soll auf einfachste Art einen Messvorgang bei einem Produkt oder Werkstück mit einer Identifikationsnummer simulieren und diese Daten später per EAP einer anderen Steuerung zur Verfügung stellen.

Für diese Aufgabe wird ein Funktionsbaustein (FB) mit der Bezeichnung GetMeasure erzeugt, der zufällig unterschiedliche Messwerte liefert und ein Hauptprogramm (MAIN) geschrieben, welches die Funktion übernimmt, auf Anfrage die ermittelten Daten zur Verfügung zu stellen.

Funktionsbaustein GetMeasure

Der FB soll folgende Eingabeparameter haben:

• NominalMeasure
  Ein Nennwert der bei dem Produkt normalerweise erwartet wird.
• Variance
  Ein Wert für die Abweichung. Die Messwertsimulation soll später einen Wert aus dem Intervall [Nennwert – 0,5 * Variance, Nennwert + 0,5 * Variance] liefern.
• Steps
  Steps legt die Schrittweite fest mit der die Abweichung auftreten kann.

Aus den Eingabeparametern (NominalMeasure = 5000, Variance = 1000, Steps = 100) soll also zufällig ein Messwert aus [4500, 4600, 4700, …, 5400, 5500] erzeugt werden, der als Ausgabeparameter vom FB zurückgeliefert wird. Für den FB GetMeasure kann der Programmcode dann folgendermaßen aussehen:

FUNCTION_BLOCK PUBLIC GetMeasure

VAR_INPUT
nominalMeasure : UDINT;
variance : UDINT;
steps : UINT;
END_VAR

VAR_OUTPUT
measure : UDINT;
END_VAR

VAR
FB_SystemTime : GETSYSTEMTIME;
currTimeLo : UDINT;
currTimeHi : UDINT;

FB_Randomizer : DRAND;
rand : LREAL;
seed : INT;

varianceEffective: UDINT;
varianceAbsolute : UDINT;
deviation : UDINT;
END_VAR

FB_SystemTime( timeLoDW => currTimeLo, timeHiDW => currTimeHi );
seed := UDINT_TO_INT(currTimeLo);
FB_Randomizer(Seed := seed, Num => rand);
varianceEffective := variance / steps;

varianceAbsolute := LREAL_TO_UINT(rand * UDINT_TO_LREAL(varianceEffective)) * steps;

IF varianceAbsolute >= (variance / 2) THEN
    deviation := varianceAbsolute - (variance / 2);    
    measure := nominalMeasure + deviation;
ELSE
    deviation := (variance / 2) - varianceAbsolute;
    measure := nominalMeasure - deviation;
END_IF;

Kopieren Sie den Programmcode in den FB GetMeasure. Anschließend öffnen Sie das Programm MAIN per Doppelklick im Editor. Hier wird nun das Hauptprogramm kodiert. Im Hauptprogramm werden eine Eingangsvariable und drei Ausgangsvariablen definiert.

Das Hauptprogramm MAIN:

Eingangsvariable:

• in_Req vom Typ BOOL
  wird verwendet, um eine Anfrage der anderen Steuerung zu erfassen.

Ausgangsvariablen:

• out_Measure vom Typ UDINT
  soll den gemessenen Wert aus dem FB GetMeasure erhalten.
• out_ProductID vom Typ UDINT
  soll eine Identifikationsnummer (ID) erhalten, die das Produkt eindeutig identifiziert.
• out_Ack vom Typ BOOL
  soll den Wert FALSE erhalten, solange noch kein Messergebnis bzw. keine ID in die entsprechenden Ausgangsvariablen geschrieben worden sind.

PROGRAM MAIN
VAR
    in_Req AT%I* : BOOL := FALSE;

    out_Measure AT%Q* : UDINT := 0;
    out_ProductID AT%Q* : UDINT := 0;
    out_Ack AT%Q* : BOOL;

    request : BOOL := FALSE;
    isReady : BOOL;

    FB_R_TRIG : R_TRIG;
    FB_F_TRIG : F_TRIG;
    FB_GetMeasure : GETMEASURE;
    FB_TON : TON;
END_VAR

(*    START:     Detecting an incomming request 
            to deliver the measure of the next product*)
    FB_R_TRIG( CLK := in_Req );
    IF FB_R_TRIG.Q THEN
        out_Ack := FALSE;
        request := TRUE;
    END_IF;

    FB_F_TRIG(     CLK := in_Req );
    IF FB_F_TRIG.Q THEN
        out_Ack := FALSE;
        request := FALSE;
    END_IF;
(*    END:     Detecting an incomming request*)

(*    START:     Simulating duration for measuring the next product*)
IF isReady THEN
    IF request THEN 
        FB_GetMeasure(    nominalMeasure := 5000, 
                        variance := 1000, 
                        steps := 100, 
                        measure => out_Measure );

        out_ProductID := out_ProductID + 1;
        request := FALSE;    
        isReady := FALSE;
        out_Ack := TRUE;
    END_IF;
ELSE
    FB_TON( PT := T#200MS, 
            IN := NOT FB_TON.Q );

    isReady := FB_TON.Q;
END_IF;
(*    END:     Simulating duration for measuring the next product*)

Das EAP Gerät

Zuletzt muss noch ein EAP Gerät bei der I/O Konfiguration in TwinCAT angelegt werden:

Nun muss das EAP Gerät noch mit einer zyklischen Task verknüpft werden, so dass es im Echtzeitkontext Variablen versenden und empfangen kann.

Aktivieren Sie Ihr TwinCAT Projekt, um später mit dem TwinCAT EAP Configurator eine Verbindung zum EAP Gerät herstellen zu können.

Das TwinCAT-Projekt Operating

Das Anlegen des TwinCAT Projektes Operating funktioniert analog wie beim TwinCAT Projekt Measuring. Es wird daher nur auf die wenigen Unterschiede und auf den Programmcode des PLC Projektes eingegangen.

Das Operating SPS Beispielprogramm

Das Operating Beispielprogramm soll auf einfachste Art einen Bearbeitungsvorgang bei einem Produkt oder Werkstück mit einer Identifikationsnummer simulieren und nach der Bearbeitung einer anderen Steuerung per EAP mitteilen können, dass das nächste Werkstück bearbeitet werden kann.

Für diese Aufgabe wird ein Funktionsbaustein (FB) mit der Bezeichnung Processing erzeugt, der die Dauer der Bearbeitung simuliert, die von einem Eingangsparameter abhängt (dem gemessenen Wert zu diesem Werkstück). Das Hauptprogramm (MAIN) übernimmt die Funktionen eine Anfrage für das nächste Werkstück zu stellen, wenn die letzte Bearbeitung abgeschlossen ist und die Bestätigung der Anfrage zu erfassen, so dass mit der Bearbeitung des nächsten Werkstücks begonnen werden kann.

Funktionsbaustein Processing

Der FB soll folgende Eingabeparameter haben:

• measure
  Der Wert der beim zu bearbeitenden Werkstück gemessen worden ist.

Der FB simuliert eine Bearbeitungsdauer, indem er den Wert des Eingabeparameters halbiert und in Sekunden wartet. Während dieser Wartezeit wird der Ausgabeparameter busy auf den Wert TRUE gesetzt, andernfalls ist der Wert FALSE. Für den FB Processing kann der Programmcode dann folgendermaßen aussehen:

FUNCTION_BLOCK PUBLIC Processing

VAR_INPUT
    measure : UDINT := 0;
END_VAR

VAR_OUTPUT
    bBusy : BOOL := FALSE;
END_VAR

VAR
    FB_TON : TON;
    bReady : BOOL;
    processingTime : TIME;
END_VAR

processingTime := UDINT_TO_TIME(measure/2);

FB_TON.PT := processingTime;
FB_TON.IN := NOT FB_TON.Q;
FB_TON();

bBusy := NOT FB_TON.Q;

Das Hauptprogramm MAIN:

Eingangsvariablen:

• in_Measure vom Typ UDINT
  soll den gemessenen Wert aus dem Projekt Measuring erhalten.
• in_ProductID vom Typ UDINT
  soll eine Identifikationsnummer (ID) erhalten, die das Produkt eindeutig identifiziert und vom Projekt Measuring mitgeteilt wird.
• in_Ack vom Typ BOOL
  soll den Wert FALSE vom Projekt Measuring erhalten, solange das nächste Werkstück noch nicht gemessen worden ist, also noch nicht zur Bearbeitung bereitsteht.

Ausgangsvariable:

• out_Req vom Typ BOOL
  wird verwendet, um das nächste Werkstück bei der anderen Steuerung anzufragen.

PROGRAM MAIN

VAR
    in_Measure AT%I* : UDINT := 0;
    in_ProductID AT%I* : UDINT := 0;
    in_Ack         AT%I* : BOOL := FALSE;

    out_Req AT%Q* : BOOL := FALSE;

    acknowledge : BOOL := FALSE;
    proceeding : UDINT := 0;

    FB_R_TRIG : R_TRIG;
    FB_F_TRIG : F_TRIG;
    FB_Processing : Processing; 
END_VAR

(*    START:     Detecting an incomming acknowledge 
            to operating the next product*)
    FB_R_TRIG( CLK := in_Ack );
    IF FB_R_TRIG.Q THEN
        acknowledge := TRUE;
    END_IF;

    FB_F_TRIG( CLK := in_Ack );
    IF FB_F_TRIG.Q THEN
        acknowledge := FALSE;
    END_IF;
(*    END:     Detecting an incomming acknowledge*)

(*    START:     Simulating duration of operating the next product*)
IF FB_Processing.bBusy THEN
    FB_Processing();    
ELSE
    IF acknowledge THEN
        acknowledge := FALSE;
        out_Req := FALSE;
        proceeding := in_ProductID;
        FB_Processing(measure := in_Measure);
    ELSE
        proceeding := 0;
        out_Req := TRUE;
    END_IF;
END_IF;
(*    END:     Simulating duration of operating the next product*)

Das EAP Gerät

Beim EAP Gerät wird bei diesem Projekt statt eines Subscribers ein Publisher mit einer Publisher Variablen vom Datentyp BOOL hinzugefügt. diese Variable wird dann mit der PLC Variablen MAIN.out_Req verknüpft.

Aktivieren Sie auch dieses TwinCAT Projekt, um später mit dem TwinCAT EAP Configurator eine Verbindung zum EAP Gerät herstellen zu können.