FB_EcCoeSdoWrite

FB_EcCoeSdoWrite 1:

Mit dem Funktionsbaustein FB_EcCoeSdoWrite kann per SDO-Download ein Objekt aus dem Objektverzeichnis eines EtherCAT-Slaves beschrieben werden. Dazu muss der Slave eine Mailbox besitzen und das "CANopen over EtherCAT (CoE)"-Protokoll unterstützen. Mit Hilfe der Parameter nSubIndex und nIndex wird ausgewählt, welches Objekt beschrieben werden soll. Für den Zugriff auf den kompletten Parameter mit Unterelementen muss der Baustein FB_EcCoeSdoWriteEx verwendet werden.

Eingänge

VAR_INPUT
    sNetId     : T_AmsNetId; 
    nSlaveAddr : UINT; 
    nSubIndex  : BYTE; 
    nIndex     : WORD;
    pSrcBuf    : PVOID; 
    cbBufLen   : UDINT; 
    bExecute   : BOOL;
    tTimeout   : TIME := DEFAULT_ADS_TIMEOUT; 
END_VAR

Name	Typ	Beschreibung
sNetId	T_Ams NetId	String, der die AMS-Netzwerkkennung des EtherCAT-Master-Gerätes enthält. (Typ: T_AmsNetId)
nSlave Addr	UINT	Feste Adresse des EtherCAT-Slaves, an den das SDO-Download-Kommando geschickt werden soll.
nSubIndex	BYTE	Subindex des Objekts, das geschrieben werden soll.
nIndex	WORD	Index des Objekts, das geschrieben werden soll.
pSrcBuf	PVOID	Adresse (Pointer) auf den Sendepuffer
cbBufLen	UDINT	Anzahl der zu sendenden Daten in Bytes
bExecute	BOOL	Über eine positive Flanke an diesem Eingang wird der Baustein aktiviert.
tTimeout	TIME	Maximale Zeit, die bei der Ausführung des Funktionsbausteins nicht überschritten werden darf.

Ausgänge

VAR_OUTPUT
    bBusy  : BOOL;
    bError : BOOL;
    nErrId : UDINT;
END_VAR

Name	Typ	Beschreibung
bBusy	BOOL	Dieser Ausgang wird bei der Aktivierung des Funktionsbausteins gesetzt und bleibt gesetzt, bis eine Rückmeldung erfolgt.
bError	BOOL	Dieser Ausgang wird gesetzt, nachdem der bBusy-Ausgang zurückgesetzt wurde, wenn bei der Übertragung des Kommandos ein Fehler auftritt.
nErrId	UDINT	Liefert bei einem gesetzten bError-Ausgang den ADS-Fehlercode des zuletzt ausgeführten Befehls.

Beispiel für eine Implementierung in ST:

PROGRAM TEST_SdoWrite

VAR
    fbSdoWrite : FB_EcCoESdoWrite;
    sNetId     : T_AmsNetId := '172.16.2.131.2.1'; (* NetId of EtherCAT Master *)
    nSlaveAddr : UINT := 1005; (* Port Number of EtherCAT Slave *)
    nIndex     : WORD := 16#4062; (* CoE Object Index *)
    nSubIndex  : BYTE := 1; (* Subindex of CoE Object *)
    nValue     : UINT := 2; (* variable to be written to the CoE Object *)
    bExecute   : BOOL; (* rising edge starts writing to the CoE Object *)
    bError     : BOOL;
    nErrId     : UDINT;
END_VAR


fbSdoWrite(
    sNetId     := sNetId,
    nSlaveAddr := nSlaveAddr,
    nIndex     := nIndex,
    nSubIndex  := nSubIndex,
    pSrcBuf    := ADR(nValue),
    cbBufLen   := SIZEOF(nValue),
    bExecute   := bExecute
);


IF NOT fbSdoWrite.bBusy THEN
    bExecute := FALSE;
    IF NOT fbSdoWrite.bError THEN 
        (* write successful *)
        bError := FALSE;
        nErrId := 0;
    ELSE 
        (* write failed *)
        bError := fbSdoWrite.bError;
        nErrId := fbSdoWrite.nErrId;
    END_IF

    fbSdoWrite(bExecute := FALSE);
END_IF

Voraussetzungen

Entwicklungsumgebung	Zielplattform	Einzubindende SPS- Bibliotheken
TwinCAT v3.1.0	PC oder CX (x86, x64, ARM)	Tc2_EtherCAT