Beispielprogramm 9 (Messbereichskombination)

In manchen Einsatzfällen kann es von Interesse sein, einen Messwert sowohl in einem kleinen Bereich sehr fein aufgelöst zu messen, aber dennoch hohe Ausschläge noch zu erfassen. Sollte es ein AC/DC-Signal sein, das um 0 herum fein aufzulösen ist, kann folgender Weg beschritten werden: es werden zwei Eingänge einer ELM‑Klemme elektrisch verbunden und messen gleichzeitig das Signal, allerdings mit unterschiedlichem Messbereich.

Der Dynamikumfang eines typischen 24 Bit Spannungs- oder Strommessbereichs liegt mit dem absoluten PDO Endwert von 2²³ (Bit 24 ist Vorzeichen) bei 20 · log(2²³) ≈ 138,5 dB (ohne Berücksichtigung von Messunsicherheiten). Nun ist es möglich, zwei (oder mehr) Eingänge eines Messsystems gleicher Messungsart mit unterschiedlichen Messbereichsendwerten (MBE1, MBE2, MBEn) parallel zu schalten um damit den Dynamikumfang zu steigern. Im Folgenden wird durch eine Kombination von zwei Eingängen die Eingangsmessgröße mit zwei Messbereichen MBE1 und MBE2 erfasst. Wird MBE2 < MBE1 gewählt und somit eine kleinere Auflösung des MBE2 als MBE1, steht einerseits die kleine Auflösung von MBE2 zur Verfügung, wenn der Betrag der Eingangsmessgröße <= MBE2 ist und andererseits kann die Eingangsmessgröße auch noch für den größeren Bereich bis <= MBE1 erfasst werden.

Hinweis: für die Berechnung des Dynamikumfangs wird hier die allgemeine Definition zugrunde gelegt:

Dynamikumfang = größter Messwert / kleinste Einheit

Zur Ausgabe in dB entsprechend dann mit 20 · log(MBE / Auflösung_MBE). In diesem Beispiel mit Kombination von MBE1 und MBE2 wird also gerechnet

Dynamikumfang = 20 · log(MBE1 / Auflösung_MBE2).

Das im Folgenden aufgeführte Beispielprogramm baut auf eine Parallelschaltung zweier Eingangskanäle der ELM3602‑0002 auf:

Programmbeschreibung/ Funktion

Der MBE1 von Kanal 1 ist mit ± 5 V und der MBE2 von Kanal 2 mit ±80 mV ausgewählt. Das Programm übernimmt den Eingangsmesswert entweder von Kanal 1 oder Kanal 2 für eine gemeinsame Variable je nach Größe des Vorzeichenlosen Betrags der Eingangsmessgröße: Initial wird auf den Grenzwert von 107% des MBE2 (8388607) geprüft.

Im CoE‑Objektverzeichnis ist gemäß den Variablen nFSV_HI und nFSV_LO in den PAI‑Settings Objekten:

0x8000:01 → ±5V

0x8010:01→ ±80mV

einzustellen. Skalierung für beide Kanäle: „Extended Range“; keine Filter aktiv (entspricht der Voreinstellung der Klemme).

PROGRAM MAIN

VAR CONSTANT

   nFSV_PDO              :  REAL := 7812500;

   nMAX_PDO              :  REAL := 8388607;

   nEXT_F                : REAL := nMAX_PDO/nFSV_PDO;

   nFSV_HI               :  REAL := 5;    // V

   nFSV_LO               :  REAL := 0.08; // V

   nStep_HI              :  REAL := nFSV_HI/nFSV_PDO;

   nStep_LO              :  REAL := nFSV_LO/nFSV_PDO;

END_VAR

VAR

   nSamplesIn1    AT%I*  :  DINT;

   nSamplesIn2    AT%I*  :  DINT;

   nValueCombi           :  LINT;

   nValueCombi_LREAL     :  LREAL;

   nKF                   :  REAL := nFSV_HI/nFSV_LO;

   nLimit                :  REAL := nMAX_PDO;

   nPDO1_REAL            :  LREAL;

   nPDO2_REAL            :  LREAL;

// Voltage values:

   nVoltage1             :  LREAL;

   nVoltage2             :  LREAL;

   nVoltageComb          :  LREAL;

END_VAR

nPDO1_REAL := DINT_TO_LREAL(nSamplesIn1);

nPDO2_REAL := DINT_TO_LREAL(nSamplesIn2);

IF ABS(nPDO2_REAL) >= nLimit THEN

   nValueCombi_LREAL := nPDO1_REAL*nKF;

ELSE

   nValueCombi_LREAL := nPDO2_REAL;

END_IF

nValueCombi := LREAL_TO_LINT(nValueCombi_LREAL);

nVoltage1 := nPDO1_REAL * nFSV_HI/nFSV_PDO;

nVoltage2 := nPDO2_REAL * nFSV_LO/nFSV_PDO;

nVoltageComb := nValueCombi_LREAL * nFSV_LO/nFSV_PDO;

Eine Anwendung dieses Beispiels mit einem ±5 V MBE1 und einen ±80 mV MBE2 und einem Eingangssignal von ±5,68 V zeigt den Spannungsverlauf an Eingang 1, Eingang 2 und beide kombinierte Eingänge als einen durchgängigen Bereich in der untersten Aufzeichnung. In der Aufzeichnung von Eingang 2 ist der Bereich des +/- Überlaufes markiert eingezeichnet (negative/ positive clipping):

Bei einer zugeführten Dreieckspannung von c.a. 86 mV ±5 mV ist der Übergangsbereich am Spannungsverlauf von „Input 2“ (Werte < 0 V) zu erkennen:

Für den (voreingestellten) „Extended Range“ beider Kanäle gilt (ohne Berücksichtigung jeglicher Messunsicherheiten):

Liegt der Dynamikumfang für den ±5 V Messbereich bei etwa 20 · log(5,368 / 6,4E‑7) ≈ 138,47 dB kann ausgehend von dem hier gezeigten Beispiel durch die Kombination von zwei Kanälen der Klemme der Dynamikumfang auf c.a. 20 · log(5,368 / 1,024E‑8) ≈ 174,39 dB gesteigert werden (mit der Einschränkung einer gröberen Auflösung im Bereich von c.a. ±85,9 mV bis ±5,37 V).

Es ist zu beachten dass die Klemme unter diesen Bedingungen aufgrund regulär auftretender Bereichsüberschreitung eines Messkanals stets Fehler über die Error-LED und dem Error-Bit anzeigt sowie Fehlermeldungen an die TwinCAT Umgebung ausgibt.